devcnt   equ   $bf31
devlst   equ   $bf32
machid   equ   $bf98
ramslot  equ   $bf26
nodev    equ   $bf10
*
*  remove  /RAM
*
ramout   php                   ;save status and make
         sei                   ;sure ints are off
         lda   machid
         and   #$30
         cmp   #$30
         bne   done            ;no /RAM
         lda   ramslot
         cmp   nodev           ;cmp low byte
         bne   cont            ;Something installed
         lda   ramslot+1
         cmp   nodev+1         ; check hi byte
         beq   done            ; no device connected
cont     ldy   devcnt
loop     lda   devlst,y
         and   #$f3
         cmp   #$b3
         beq   getloop
         dey
         bpl   loop
         bmi   done
getloop  lda   devlst+1,y      ;get next unit #
         sta   devlst,y        ;move it up in list
         beq   exit
         iny
         bne   getloop
exit     lda   nodev           ;copy nodev connected
         sta   ramslot         ;into slot 3 drive 2
         lda   nodev+1
         sta   ramslot+1
         dec   devcnt
done     plp                   ;reset status
         rts


Pim Blokland <nipp@nipp.nl> wrote in message
news:nipp-55DEBD.21070411012000@news.planet.nl...
> In article <uvsGGDFX$GA.277@cpmsnbbsa04>, "laine_h"
> <laine_h@email.msn.com> wrote:
>
> > > I have the ProDOS Technical Reference Manual, but there is nothing...
>
> > 5.2.2.2 page 90
>
> Whoa... must have missed that. The index does not refer to that page.
> In my manual, it's page 91, by the way. And it's chapter 5.2.2, not
> 5.2.2.2. And it says that the high nibble of the RAM disk device is 8,
> while in reality, there is no such device in the list. And there is no
> mention whatever of what to do with the drive vector table, only the
> device table. Or how to restore the RAM disk.
> Did I mention that this is a VERY old ProDOS manual? So old that it
> mentions that ProDOS can run in 48K? Maybe I should buy a new one.
> --
> Groetjes, Pim
>