Welcome to 1988, fellow ProDOS users!
 
If you are using ProDOS 1.1.1 and have a clock card in your
machine, your system may not have welcomed to the new year quite
so nicely. The Thunderclock driver in ProDOS calculates the year
based on the date & day of week, and 1988 is indistinguishable
from 1982 (at least this time of year). ProDOS 1.1.1 "knows" that
the year is always from 1981 to 1987.
 
If you're having "1982" problems with your system, do one of the
following:
 
1. Get ProDOS 8 1.4 from the SYSTEM directory of a IIgs System
Disk. It is called P8, but you can copy it into the main
directory of your ProDOS 8 disks and call it PRODOS.
 
2. Run the following program after setting your PREFIX to the
disk containing the ProDOS you want to patch. This program is
FIXDAT.FP from DL1 of APPLEII on CompuServe. After running,
things will be peachy until 1992 or thereabouts.
 
 ----- cut here
 NEW
 10REMFix year list in ProDOS 1.1.1
 20REMGlen E. Bredon.
 30REM
 40TEXT:?:HOME:HTAB8
 50?"PRODOS 1.1.1 DATE FIXER"
 100E=0
 110FORI=0TO6:READOY(I):NEXTI
 120FORI=0TO6:READNY(I):NEXTI
 130VTAB12:?"Now patching ProDOS.":?:?
 140ONERRGOTO270
 150IFPEEK(116)<128THENE=1:GOTO270:REMIs mem free?
 160?CHR$(4)"unlock prodos"
 170?CHR$(4)"bload prodos,tsys,a$2000"
 180ADR=4*4096+118
 190P=0:FORI=0TO6:IFPEEK(ADR+I)<>OY(I)THENP=1
 200NEXTI
 210IFADR>6*4096THENE=3:GOTO270
 220IFPTHENADR=ADR+256:GOTO190
 230FORI=0TO6:POKEADR+I,NY(I):NEXTI
 240?CHR$(4)"bsave prodos,a$2000,tsys"
 250?:?"Date patch completed."
 260END
 270?CHR$(7)"Error! No patches were made.":?
 280ONEGOTO300,310,320
 290?"PRODOS file not found.":END
 300?"Insufficient memory to load PRODOS.":END
 310?"Patch location not found."
 320?"PRODOS file may have been patched"
 330?"already, or is not a compatible version."
 1000DATA84,84,83,82,87,86,85
 1010DATA90,89,88,88,87,92,91
 SAVE PATCH.DATE