;--------------------------------
; MASTER MIND
; AUTHOR: KEN WESSEN
;--------------------------------
TRIES   .EQ $E2
RNDL    .EQ $E3
RNDH    .EQ $E4
RND2L   .EQ $E5
N       .EQ $E6
GUESS   .EQ $EB
CR      .EQ $8D
;
COUT    .EQ $FFEF
PRBYTE  .EQ $FFDC
KBD     .EQ $D010
STROBE  .EQ $D011
;
MSTMIND LDX #8
.1      LDA MSG-1,X
        JSR COUT
        DEX
        BNE .1
        STX TRIES
.2      INC RNDL
        BNE .3
        INC RNDH
.3      LDA STROBE
        BPL .2
        JSR CHARIN
.4      SEC
        SED
        TXA
        ADC TRIES
        STA TRIES
        CLD
.5      JSR CRLF
        LDA TRIES
        JSR PRBYTE
        LDA #" "
        TAY
        JSR COUT
        LDA RNDL
        STA RND2L
        LDA RNDH
        LDX #5
.6      STY N-1,X
        LDY #3
.7      LSR
        ROL RND2L
        ROL N-1,X
        DEY
        BNE .7
        DEX
        BNE .6
.8      JSR CHARIN
        JSR COUT
        EOR #"0"
        CMP #8
        BCS .5
        STA GUESS+4,X
        DEX
        CPX #$FB
        BNE .8
        LDY #$FB
        LDA #" "
.9      JSR COUT
.10     LDA GUESS+5,X
        CMP N+5,X
        BNE .11
        STY N+5,X
        LDA #"+"
        STA GUESS+5,X
        INY
        BNE .9
        LDX #$11
        BNE .1
.11     INX
        BNE .10
        LDY #$FB
.12     LDX GUESS+5,Y
        TXA
        LDX #$FB
.13     CMP N+5,X
        BNE .14
        STY N+5,X
        LDA #"-"
        JSR COUT
.14     INX
        BNE .13
        INY
        BNE .12
        BEQ .4
;
MSG     .AS -/?YDAER/
        .DA #CR,#CR
        .AS -/NIW UOY +/
;
CRLF    LDA #CR
        JMP COUT
;
CHARIN  LDA STROBE
        BPL CHARIN
        LDA KBD
        RTS