NEW
10REM---------------------------
11REMMaster CDA maker
12REMby Glen E. Bredon
13REM
14REMCommercial rights reserved.
15REM---------------------------
16REMPut the CDAs you want to
17REMmerge into a directory with
18REMthis program and MASTER.DA.
19REMThen run this program.
20REM---------------------------
21REM
100LOMEM:8*4096
110DIMP$(100)
120?CHR$(4)"pr#3":?CHR$(12)
130?TAB(32)"MASTER CDA MAKER"
140?:?TAB(33)"by Glen Bredon"
150?:?
160?"Enter CDA pathnames carefully."
170?"Empty input signals no further CDAs to process."
180?
190?CHR$(4)"bload master.da,t$b9,a$1000"
200PNT=PEEK(4096+69)+9:NUM=4096+PNT+60
210SIZ=PEEK(48859)+256*PEEK(48860)
220DIC=4096+SIZ-1
230ONERRGOTO5000
240?"Pathname of CDA #";I+1;:INPUT": ";P$
250IFP$=""THEN1000
260P$(I)=P$
270?CHR$(4)"verify ";P$
280POKE216,0
290POKEDIC,246:POKEDIC+1,3:POKEDIC+2,0
300POKEDIC+3,PNT:POKEDIC+4,PHI
310POKEDIC+5,I+2:POKEDIC+6,0:POKEDIC+7,0:POKEDIC+8,0
320DIC=DIC+8
330SIZ=SIZ+8:PNT=PNT+3:IFPNT>255THENPNT=PNT-256:PHI=1
340I=I+1:IFI<100THEN230
1000POKE216,0:BLOCKS=INT((SIZ-1)/512)+1:POKE4096,BLOCKS
1010?:INPUT"Give a unique number to this master list (0-9):";N$
1020IFLEN(N$)<>1THEN1010
1030IFN$<"0"ORN$>"9"THEN1010
1040POKENUM,VAL(N$)+ASC("0")
1050?:INPUT"Name to call this file:";P$
1060?CHR$(4)"create ";P$;",t$b9"
1070?CHR$(4)"bsave ";P$;",t$b9,a$1000,l";SIZ
2000FORJ=1TOI
2010?CHR$(4)"bload ";P$(J-1);",t$b9,a$1000"
2020POKE4096+34,J+1
2030SIZ=PEEK(48859)+256*PEEK(48860)
2040?CHR$(4)"bsave ";P$;",t$b9,a$1000,b";BLOCKS*512;",l";SIZ
2050BLOCKS=BLOCKS+INT((SIZ-1)/512)+1
2060NEXTJ
3000?:?"All done.  Remove, if necessary, those CDAs from the SYSTEM/DESK.ACCS"
3010?"directory and put <";P$;"> there."
3020END
5000CALL62248:?"File not found, please try again."
5010GOTO230
SAVE MASTER.MAKER